unknownplace.org

Catalystは Authentication::Credential::* プラグインを複数使うことにより、複数の認証方式に対応できる。

IP認証などのような、Credプラグインが提供されていないものも即席でCredインタフェースにそったモジュールを作ることで簡単に認証方法を追加することができる。

MyApp.pm はこんな感じ

package MyApp;

use strict;
use warnings;

use Catalyst::Runtime '5.70';
use Catalyst qw/
    ConfigLoader

    Authentication
    Authentication::Credential::HTTP
    +MyApp::Credential::IP
    Authentication::Store::DBIC
    /;

our $VERSION = '0.01';

__PACKAGE__->setup;

Cred::HTTP が Basic 認証用のモジュール。+MyApp::Credential::IP がIP認証用のオリジナルモジュール。

この MyApp::Credential::IP のコードはこんな感じ。

package MyApp::Credential::IP;
use strict;
use warnings;
use base qw/Catalyst::Plugin::Authentication::Credential::Password/;

sub authenticate_from_address {
    my $c = shift;

    my $ip = $c->model('DBIC::UserIp')->find({ ip => $c->req->address }, { prefetch => 'user' })
        or return;
    my $user = $c->get_user( $ip->user->username )
        or return;

    $c->set_authenticated($user);

    1;
}

1;

こんな短いコードで認証増やせるの。なかなか便利。

で、実際に利用するのは以下のように、Root Controller の auto アクションに

sub auto :Private {
    my ($self, $c) = @_;

    # basic auth
    $c->authenticate_http and return 1;

    # ip auth
    $c->authenticate_from_address and return 1;

    # return basic auth response when no auth success
    $c->authorization_required_response( realm => 'Require Authentication' );
    return;
}

などとする。

全体に認証かけたいときはルートコントローラの auto に、コントローラ個別に指定したいときは、上記コードを埋め込んだ認証用の親コントローラクラスつくって認証必要なコントローラはそれを継承する。

パスごとにやりたいときは Authentication::ACL ってのがあるけど僕は使っていない。